On-line: гостей 2. Всего: 2 [подробнее..]
Правила: заголовок темы должен кратко и понятно отражать ее суть, нельзя писать латиницей или заглавными буквами. Сообщение, ник, аватар не должны выделяться своими размерами или стилем написания от остальных, быть читабельными, написаны литературно и достаточно грамотно.



АвторСообщение



Сообщение: 119
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 03.12.13 08:35. Заголовок: Translate моделей Microcap -> ORcad и другие симуляторы и обратно


Нередко возникает необходимость переноса модели, созданной в Microcap, на платформы других симуляторов или наоборот использования в Microcap моделей сторонних производителей. Причин тому можно назвать предостаточно. Поэтому предлагается использовать эту ветку для обсуждения подобного рода задач, чтобы не загружать прочие несвойственной тематикой.

Спасибо: 0 
ПрофильЦитата Ответить
Ответов - 27 , стр: 1 2 All [только новые]





Сообщение: 255
Зарегистрирован: 24.03.12
Откуда: Россия, Саратов
Рейтинг: 1
ссылка на сообщение  Отправлено: 08.12.14 04:29. Заголовок: не думал что понадоб..


не думал что понадобится.но вот нашел модель LM3886,LM1875 и подобные
усилители.расширение olb.кажется оркадовская.как переделать на стандартный
спайс не знаю.хочется попробовать,что же реально будет с кни.
может зря я на дискретных делаю.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 12
Зарегистрирован: 02.07.14
Откуда: Ярославль
Рейтинг: 0
ссылка на сообщение  Отправлено: 08.12.14 11:47. Заголовок: Сама библиотека нахо..


Сама библиотека находится в .lib файле. Но судя по директиве $CDNENCSTART она зашифрована, и работать с ней может только оркад... :(

Когда сам впервые столкнулся с такой проблемой, смог только модельку для тины дешифровать. Повезло, что разработчики тины криворукие.

Но у меня тогда в микрокапе так и не получилось заставить работать ту дешифрованную модель, зато в других симуляторах LTspice, SIMetrix, Orcad всё работало чётко...



Вот дешифрованные модельки LM1875, LM3886 из тины https://yadi.sk/d/SoqodZfTdDk5Q
Авось заработают в микрокапе...

Конкретно на эти микросхемы в гугле можно найти самодельные модельки, но на сколько они близки к реальности сказать трудно...


Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 42
Зарегистрирован: 21.08.07
Рейтинг: 0
ссылка на сообщение  Отправлено: 10.12.14 05:18. Заголовок: Модель LM3886


Не помню, где брал, но работает, может и не точно.
.SUBCKT LM3886 posin negin out posrail negrail mute gndpin
* IN+ IN- OUT VCC VEE MUTE GND
*
* LM3886 spice model by teemuk 21032007 ver.1b
Q1 posrail posin N004 0 NPN
I1 N004 negrail 0.25m
Q2 posrail negin N003 0 NPN
I2 N003 negrail 0.25m
Q3 N011 N003 N010 0 PNP
Q4 N011 N018 N012 0 NPN
R1 N012 negrail 2.2k
I3 N018 negrail 0.1m
Q5 N017 N018 N024 0 NPN
R2 N024 negrail 2.2k
Q6 posrail N011 N018 0 NPN
R3 N009 N010 1.1k
R4 N009 N023 1.1k
Q7 N017 N004 N023 0 PNP
Q8 N017 N013 N016 0 PNP
Q9 N011 N025 N019 0 PNP
R5 N015 N016 4.7k
R6 N015 N019 4.7k
R7 N013 gndpin 10k
D1 N025 gndpin D
D2 gndpin N025 D
R8 out N025 10k
C1 out N017 10p
I4 N026 negrail 1m
Q10 posrail N017 N026 0 NPN
Q11 N030 N026 N031 0 NPN
R9 N031 negrail 800
Q12 N009 N008 N014 0 PNP
Q13 N015 N022 N014 0 PNP
I5 posrail N014 1m
I6 N022 negrail 1m
D3 N021 N022 D
D4 N020 N021 D
R10 posrail N020 1k
D5 N007 N008 D
D6 N006 N007 D
R11 posrail N006 1k
Q14 N008 gndpin N005 0 NPN
R12 N005 N001 1k
D7 N002 mute D
D8 N001 N002 D
D9 N032 N031 D
R13 N034 negrail 150
Q15 out N032 N034 0 NPN
Q16 out N034 N036 0 NPN
R14 N036 negrail 0.45
Q17 N032 N030 out 0 PNP
D10 N029 N030 D
D11 N028 N029 D
D12 N027 N028 D
R15 N033 out 150
Q18 posrail N027 N033 0 NPN
Q19 posrail N033 N035 0 NPN
R16 N035 out 0.45
I7 posrail N027 2.5m
.model D D
.model NPN NPN
.model PNP PNP
.ends lm3886


Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 257
Зарегистрирован: 24.03.12
Откуда: Россия, Саратов
Рейтинг: 1
ссылка на сообщение  Отправлено: 10.12.14 05:39. Заголовок: kreking ,спасибо.эту..


kreking ,спасибо.эту модель тоже где то нашел и вставил.
параметры показывает близкие по кни,но смущают транзисторы c установками
по умолчанию.по тексту трудно понять нюансы.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 177
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 10.12.14 09:27. Заголовок: To locik В добавлен..


To locik
В добавление к обсуждаемой теме. Аккуратную модель LM1875, заимствованную из Мультисима, можно скачать по ссылке
https://yadi.sk/d/8YZEhjzldGgyo
Проверил в МС9, все работает как в datdsheet. Просто поместите файл в папку LIB и проведите процедуру добавления компонента. Модель LM3886 есть в Тине10, но она не показывает содержимое листинга. Пишет, что оно не отображается. Если есть необходимость, можно промоделировать в этом симуляторе, предварительно скачав триальную версию.

To Орлёнок
Вы как-то писали, что Вам удалось раскодировать модель LM3886. Не могли бы рассказать об этом подробнее.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 258
Зарегистрирован: 24.03.12
Откуда: Россия, Саратов
Рейтинг: 1
ссылка на сообщение  Отправлено: 11.12.14 04:32. Заголовок: qaki ,не работает LM..


qaki ,не работает LM1875 в мультисим.показывает кни 0.001%.
это очень подозрительно.в даташите гораздо больше.
у меня тина 8.скачал для нее макро на сайте тины(LM1875).в ней показывает что то реальное.
но выше чем в даташите.а вот LM 3886 они удалили.наверное,чтобы качали
новые версии тины.
в общем который раз убеждаюсь,пока спайс не знаешь одни проблемы.
надо учиться писать модели.


Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 178
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 11.12.14 13:00. Заголовок: locik пишет: qaki ,..


locik пишет:

 цитата:
qaki ,не работает LM1875 в мультисим.показывает кни 0.001%.
это очень подозрительно.


Так что удивительного. Комбинации на уровне -100 дБ. Работает глубокая отрицательная обратная связь. Прога дубово считает по формуле, где все делится на коэффициент усиления разомкнутой цепи. Если КУ 100 дБ, то всякие паразиты будут на уровне -100 дБ. А вообще динамический диапазон по комбинациям во входных цепях хороших радиоприемников достигает 130 дБ.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 180
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 22.12.14 10:15. Заголовок: LM3886


to locik
Если еще не потеряли интерес, то официальную, но слегка подправленную для работы в Микрокап модель LM3886 можете скачать отсюда
https://yadi.sk/d/qPqxfrdMdXas4

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 262
Зарегистрирован: 24.03.12
Откуда: Россия, Саратов
Рейтинг: 1
ссылка на сообщение  Отправлено: 22.12.14 14:19. Заголовок: qaki ,спасибо.скачал..


qaki ,спасибо.скачал.попробую.извините,пока интерес пропал к интегральным
усилителям.попробую на дискретных собрать.
для моей MicroLab B-62 нужен низковольтный.питание всего 14 вольт.
на тда2003 и подобных не хочу делать.кни большой.и коэффициент
использования ИП плоховат.
все хочу переделать.послушать как же будет звучать.с ПП правда проблемы.
не получается хотя бы на троечку сделать.но переделывать уже не буду.
5 раз уже делал заново.каждый раз размещать элементы,которые должны
стоять точно по конструкции корпуса уже как то устал.
вот давно заметил одну интересную особенность.иногда МР3 128кб/c звучит лучше
чем 192.парадокс.но субъективно такое ощущение.по законам физики это
непонятно.высоких нет,а звук есть.а у 192 и высоких побольше,а звука нет.
он какой то неестественный.как говорят "непрозрачный".

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 263
Зарегистрирован: 24.03.12
Откуда: Россия, Саратов
Рейтинг: 1
ссылка на сообщение  Отправлено: 22.12.14 16:37. Заголовок: не а.не работает.пиш..


не а.не работает.пишет те же ошибки.как в предыдущей где то скачанной.
кажется орленок давал подобную.
картинка


Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 181
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 22.12.14 23:19. Заголовок: locik пишет: а.не р..


locik пишет:

 цитата:
а.не работает...


Как это, как это, как это... Во первых отключите mute от минуса. По этому входу усилок затыкается, дабы не травить слишком поднятыми басами несчастных любителей ночной тишины. Интересная вещь. Автомузыка внутри салона звучит вполне комфортно, но на расстоянии 50 м страшно давит на уши и брюшину. Задумываюсь о том, как бы заглушить балалайки пьяных отморозков с помощью СВЧ печки, переведенной в импульсный режим.
Во вторых проверьте снята ли у Вас вот эта галочка на панели глобальных установок

Эта птичка блокирует автоматическую установку резистора 10 МОм на узлы, не имеющие связи с землей. B PSpice такая установка номинальный режим, В Микрокапе - опция. Посмотрите netlist модели. Я специально добавил установку этой и других опций.
Ну и наконец, попробуйте запустить мой файл .CIR
https://yadi.sk/d/zqZRL6lTdYjWZ

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 264
Зарегистрирован: 24.03.12
Откуда: Россия, Саратов
Рейтинг: 1
ссылка на сообщение  Отправлено: 23.12.14 00:16. Заголовок: Да,извиняюсь.постави..


Да,извиняюсь.поставил эту опцию и отключил муте.и все заработало
в МС9.если такой кни будет реально или близкий,это хорошо.
в той первой модели где просто много транзисторов без муте почему то не
работала.или я что то напутал.я просто заменил в схеме на новую модель,но не учел нюансов.
в салоне вообще все звучит немного по другому.как то больше объемность звука.
если конечно слушать на нормальной громкости,а не когда давит на уши.
насчет СВЧ это слишком.выход-дать им гитары.пусть лучше учаться,чем бред
всякий слушать по ФМ.


Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 182
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 23.12.14 08:21. Заголовок: to locik Кстати, мод..


to locik
Кстати, модель LM5116, о которой писал Орлёнок, при снятии этой галочки тоже работает. Видимо это общий приемчик при использовании PSpice моделей, написанных под OrCAD. Вот только сам Орлёнок что-то молчит и не хочет поделиться секретом расшифровки моделей от ТI. Внешне эти произведения напоминают шифрование с открытым ключом. По крайней мере первая строка у всех зашифрованных моделей одинакова. Попробовал скормить Мультисиму одну модельку от Тины. Так тот просто рехнулся. Почти час рисовал какие-то безумные картины на мониторе, а в конце намертво завис.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 265
Зарегистрирован: 24.03.12
Откуда: Россия, Саратов
Рейтинг: 1
ссылка на сообщение  Отправлено: 23.12.14 22:14. Заголовок: у меня 1 раз с мульт..


у меня 1 раз с мультисимом было еще хуже.после такой попытки слетел
файл конфигурации.он тоже долго что то рисовал,потом улетел.
после запуска интерфейс нарушен.почти все отсутствует.
такие сложные CIRы в него лучше не вставлять.пришлось искать старенький
конфиг и заново настраивать.
с моделью LM5116 попробую,если еще не удалил.да,надо признать совсем
забыл про эту особенность микрокапа.давно снял эту галочку и забыл про это.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 266
Зарегистрирован: 24.03.12
Откуда: Россия, Саратов
Рейтинг: 1
ссылка на сообщение  Отправлено: 24.12.14 00:25. Заголовок: промоделировал.дейст..


промоделировал.действительно работает LM5116.
впечатляет ток индуктивности.ах уж эта опция.


Спасибо: 0 
ПрофильЦитата Ответить



Не зарегистрирован
Зарегистрирован: 04.01.17
Рейтинг: 0
ссылка на сообщение  Отправлено: 04.01.17 01:53. Заголовок: qaki qaki пишет: ..


qaki qaki пишет:
[quote]`

официальную, но слегка подправленную для работы в Микрокап модель LM3886 можете скачать отсюда

Залейте пожалуйста еще раз файл LM3886. Ото та ссылочка уже не работает. Спасибо.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 211
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 04.01.17 17:33. Заголовок: AlexDu пишет: Залей..


AlexDu пишет:

 цитата:
Залейте пожалуйста еще раз файл LM3886.


К сожалению помочь не смогу. Модель из Яндекс-диска была удалена за отсутствием интереса к ней, а первичные материалы остались на диске старого компьютера. Перенести их полностью на диск нового не получилось.

Спасибо: 0 
ПрофильЦитата Ответить



Не зарегистрирован
Зарегистрирован: 01.01.70
ссылка на сообщение  Отправлено: 05.01.17 17:27. Заголовок: если очень нужно мог..


если очень нужно могу поискать.где то осталась схема с этой моделью.

Спасибо: 1 
Цитата Ответить



Сообщение: 212
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 05.01.17 17:43. Заголовок: To Alex Du Кое-что в..


To Alex Du
Кое-что все таки нашлось. Вот свежая ссылка на расшифрованную модель от TI: https://yadi.sk/d/sfpv6wZO378DcK .
Обращаю Ваше внимание на процесс добавления модели. Модель поместите в папку LIBRARY.
На этапе выбора Shape ориентируйтесь на подходящую картинку из операционников. Можносделать как у меня [img] [/img]
Заметьте, что микруха LM3886 и соответственно ее модель работают с плавающим нулем, что вполне разумно с точки зрения схемотехники, но является сущей крамолой для Микрокапа. Поэтому при запуске анализа нужно обязательно снять галочку в строке PATH_TO_GROUND, о чем писалось ранее. Модель проверена и работает вполне нормально

Спасибо: 1 
ПрофильЦитата Ответить



Сообщение: 1
Зарегистрирован: 04.01.17
Рейтинг: 0
ссылка на сообщение  Отправлено: 06.01.17 15:02. Заголовок: qaki Спасибо за моде..


qaki Спасибо за модель.
Заработала в 11 МС, в моем старом МС9 отказалась работать (видимо что-то в нем подрезано, к примеру, отсутствует выбор PATH_TO_GROUND, зато в 11 МС эта функция есть).
Обнаружил одно не соответствие с документацией на LM3886 по входу MUTE. В сообщениях выше от вас видел заблуждения по режиму работы этого входа.

Из PDF на LM3886
Pin 8 Open or at 0V, Mute: On
Current out of Pin 8 > 0.5 mA,
Mute: Off

Из других источников
Резистор в цепи Mute (источник тока 0,5 мA) для управления выхода MUTE Rm рассчитывается по формуле Rm < (VEE-2.6V)/I, где I > 0.5mA. ВНИМАНИЕ!!!!! Если выход Mute не подключен через этот резистор к минусу питания, а висит в воздухе или на землю – то микросхема играть не будет.


Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 213
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 06.01.17 15:52. Заголовок: To AlexDu Спасибо з..


To AlexDu
Спасибо за сообщение. Вы правы. Если посмотреть на эквивалентную схему микрухи, то можно видеть, что по входу Mute производится управление токовым зеркалом первого каскада усилителя. Если Mute висит в воздухе, то токовое зеркало заперто. Когда проверял работу модели, то пробовал менять величину сопротивления резистора, включенного между минусом и Mute. Оказалось, что переход из закрытого состояния в открытое происходит довольно резко, достаточно изменить величину сопротивления буквально на единицы процентов. Ну, а в общем, аудиотехника меня мало интересует. Для меня эталоном музыкального звучания является стейнвеевский рояль при исполнении Шопена или блютнеровский для Шумана.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 214
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 06.01.17 18:00. Заголовок: Что-то не то написал..


Что-то не то написал в предыдущем сообщении. Если на Mute ничего не подавать, то усилок открыт и при питании +28 В/-28 В выдает на нагрузку 8 Ом при Uвх=1 В как и положено для типовой схемы из datasheet 20 В. Ставим резистор с -28 В на Mute 20 кОм. При его подключении усилок запирается. Но вот с другим вариантом дешифрованной модели (от Орленка) вообще чудеса. При штатной полярности питания Микрокап пишет про сингулярность. Если полярность поменять на противоположную, то начинает работать. Видимо в net-list или в зашифрованном исходнике что-то напутано.

Спасибо: 0 
ПрофильЦитата Ответить





Сообщение: 1
Зарегистрирован: 05.06.16
Рейтинг: 0
ссылка на сообщение  Отправлено: 11.02.19 20:38. Заголовок: qaki пишет: К сож..


qaki

К сожалению ссылка на найденную Вами модель LM3886 нерабочая.

Если есть у кого возможность поделитесь пожалуйста переработанной моделью из Tina.Хочется именно подробную модель LM3886 чтоб поиграться в композитном включении.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 172
Зарегистрирован: 20.10.13
Откуда: 777RUS
Рейтинг: 3
ссылка на сообщение  Отправлено: 26.02.19 15:39. Заголовок: http://www.ti.com/pr..

Спасибо: 0 
ПрофильЦитата Ответить





Сообщение: 2
Зарегистрирован: 05.06.16
Рейтинг: 0
ссылка на сообщение  Отправлено: 28.02.19 15:39. Заголовок: Emc, не получилось(и..


Emc, не получилось(и не у меня одного) сделать рабочую модель от TI.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 285
Зарегистрирован: 22.04.09
Рейтинг: 1
ссылка на сообщение  Отправлено: 28.02.19 22:27. Заголовок: Sergey Kor пишет: н..


Sergey Kor пишет:

 цитата:
не получилось(и не у меня одного) сделать рабочую модель от TI.


Затаривай! Режим тишины (Mute) подключается 7-й ногой на минус питания

* LM3886
* Version 1.0 :
* Free for Microcap
*
*****************************************************************************
* Notes:
* The LM3886 Macro Model represents the following parameters for
* split-supply operation (+/-28V):
* GBWP, input-referred voltage noise, the quiescent current,
* output swing, input offset voltage, input bias current, PSRR,
* CMRR, and the slew rate.
*
*****************************************************************************
*$
.SUBCKT LM3886 INP INN VCC VEE GND OUT MUTE
*
V_Vos INP2 INP_CMRR -1056uVdc
R_Rinp INP INP1 1
R_Rinn INN INN1 1
C_Cinp GND INP1 200f
C_Cinn GND INN1 200f
E_E1 VCC_BUF GND VCC GND 1
E_E2 VEE_BUF GND VEE GND 1
R_RMUTE VCC MUTE 1e6
X_UIcc VCC VEE MUTE VIMON GND INP2 INN1 HPA_PD_I
+ PARAMS: VTH=1.4I IMAX=50e-3 IMIN=0.444e-3 IIBP=210n IIBN=200n
G_G1 GND N2B INP_CMRR GND 3.2u
E_Ecmrr INN2 INN3 N2B GND 1
R_Rcmr N2B N2 1
L_Lcmr N2 GND 560nH
G_G2 GND N1B VCC_BUF VEE_BUF 1u
L_Lpsr N1 GND 2uH
R_Rpsr N1B N1 1
X_Upsrr N1B GND INN1 INN2 VCVS_LIMIT
+ PARAMS: GAIN=-1 VPOS=20M VNEG=-20M
X_Uvn INP1 INP2 VNSE
*
V_V1 VCC N3 3.59Vdc
V_V4 N4 VEE 3.59Vdc
X_Ud2 INN3 N3 d_ideal
X_Ud1 INP_CMRR N3 d_ideal
X_Ud3 N4 INP_CMRR d_ideal
X_Ud4 N4 INN3 d_ideal
*
X_Ug0 INP_CMRR INN3 GND AV1 VCCS_LIMIT
+ PARAMS: GAIN=10e-6 IPOS=0.5 INEG=-0.5
X_Ug4 AV1 GND GND OVER_CLAMP VCCS_LIMIT
+ PARAMS: GAIN=26.5u IPOS=107.5u INEG=-107.5u
GRU1 GND AV1 VALUE={V(GND ,AV1 )/1e6}
GRU2 GND OVER_CLAMP VALUE={V(GND ,OVER_CLAMP)/2.1e9}
C_Cc1 GND OVER_CLAMP 5.3p
C_Cc2 P0ZP1 GND 5e-15
C_Cc3 CLAW_CLAMP GND 995f
*
X_UIout VCC VEE VIMON GND TRAN_IOUT
G_G3 GND VSENSE OVER_CLAMP GND 1u
G_G4 GND P0Z VSENSE GND 1u
G_G5 GND P0ZP1 P0Z GND 1u
G_G6 GND CLAW_CLAMP P0ZP1 GND 1m
G_G7 GND CL_CLAMP CLAW_CLAMP GND 1m
GRU3 VSENSE GND VALUE={V(VSENSE,GND )/1e6}
GRU5 GND P0Z VALUE={V(GND , P0Z )/1e6}
GRU6 P0ZP1 GND VALUE={V(P0ZP1, GND )/1e6}
GRU7 CLAW_CLAMP GND VALUE={V(CLAW_CLAMP,GND )/1e3}
GRU8 CL_CLAMP GND VALUE={V(CL_CLAMP, GND )/1e3}
*
X_UpwrDn CL_CLAMP GND MUTE N90 GND VCC VEE HPA_PD_SGNL
*

XVoclp VCC VEE N90 N94 Vimon1 GND VCLAMP_W_SENSE_0
+ PARAMS: VMAXIO=1.55 VMINIO=2.45 SLOPE=0
XIoclp VCLP N94 RNOISE_LESS_WILIM_0
+ PARAMS: RX=0.01 IMAX=11.5 IMIN=-11.5
XUA VCLP Uz_VZO_4 Vimon1 GND AMETER_0
*
X_Uz_H1 Uz_VZO_4 OUT VIMON GND Zout_Uz_H1
E_Uz_E1 Uz_VZO_2 GND Uz_VZO_1 Uz_VZO_4 -1
R_Uz_Ra Uz_N106 Uz_VZO_4 10
R_Uz_Rb Uz_N104 Uz_VZO_4 10
R_Uz_Rm Uz_VZO_3 Uz_VZO_4 10
X_Uz_S1 N92 GND Uz_N106 Uz_VZO_3 Zout_Uz_S1
X_Uz_S2 N92 GND Uz_N104 Uz_VZO_3 Zout_Uz_S2
GRUz_Rg1 GND Uz_N100 VALUE={V(GND ,Uz_N100)/10e6}
GRUz_Rf1 Uz_N100 Uz_VZO_1 VALUE={V(Uz_N100 ,Uz_VZO_1)/10e6}
GRUz_Rg2 Uz_VZO_2 Uz_N102 VALUE={V(Uz_VZO_2,Uz_N102 )/1e6}
GRUz_Rf2 Uz_N102 Uz_VZO_3 VALUE={V(Uz_N102 ,Uz_VZO_3)/1e6}
X_Uz_Uamp1 VCLP Uz_N100 Uz_VZO_1 GND VCVS_LIMIT
+ PARAMS: GAIN=1e6 VPOS=6e4 VNEG=-6e4
X_Uz_Uamp2 GND Uz_N102 Uz_VZO_3 GND VCVS_LIMIT
+ PARAMS: GAIN=1e6V VPOS=6e4 VNEG=-6e4
*
.ENDS LM3886
*$
*
.subckt Zout_Uz_S1 1 2 3 4
S_Uz_S1 3 4 1 2 _Uz_S1
RS_Uz_S1 1 2 1G
.MODEL _Uz_S1 VSWITCH Roff=10e6 Ron=1.0 Voff=-0.1V Von=0.1V
.ends Zout_Uz_S1
*$
.subckt Zout_Uz_S2 1 2 3 4
S_Uz_S2 3 4 1 2 _Uz_S2
RS_Uz_S2 1 2 1G
.MODEL _Uz_S2 VSWITCH Roff=10e6 Ron=1.0 Voff=0.1V Von=-0.1V
.ends Zout_Uz_S2
*$
.subckt Zout_Uz_H1 1 2 3 4
H_Uz_H1 3 4 VH_Uz_H1 1e3
VH_Uz_H1 1 2 0V
.ends Zout_Uz_H1
*
*$
.subckt rnoiseless a b PARAMS: R=1k
*H_H1 c b VH_H1 {R}
*VH_H1 a c 0
ERES a 3 VALUE = { I(VSENSE) * R }
Rdummy 30 3 1
VSENSE 30 b DC 0V
.ends
*$
*
.SUBCKT EPOLY1 1 2 3 4 PARAMS: Coeff1=0.0 Coeff2=0.0
*For distortion purpose
*EINT 3 4 POLY(1) (1,2) (0 1 Coeff1 Coeff2)
EINT 3 4 POLY(1) (1,2) (0 1 0 0)
.ENDS EPOLY1
*$
*
.subckt D_ideal A C
D1 A C DNOM
.MODEL DNOM D (IS=1e-16 RS=1e-3 N=1e-3)
.ENDS D_ideal
*
*$
.subckt VCCS_Limit VCP VCN IOUTP IOUTN PARAMS: Gain = 1.7e-3
+ Ipos = 0.100 Ineg = -0.165
G1 IOUTP IOUTN VALUE={LIMIT(Gain*V(VCP,VCN),Ipos,Ineg)}
.ends VCCS_Limit
*
*$
.subckt VCVS_Limit VCP VCN VOUTP VOUTN PARAMS: Gain = -1
+ Vpos = 20m Vneg = -20m
E1 VOUTP VOUTN VALUE={LIMIT(Gain*V(VCP,VCN),Vpos,Vneg)}
.ends VCVS_Limit
*$
*
.SUBCKT VNSE 1 2
**************************
* BEGIN SETUP OF NOISE GEN - NANOVOLT/RT-HZ
* INPUT THREE VARIABLES
* NLF - NV/RHZ AT (1/F) FREQ
* FLW - FREQ FOR (1/F) VAL
* NVR - NV/RHZ FLATBAND
**************************
* START CALC VALS
.PARAM NLF=20.2
.PARAM FLW=1
.PARAM NVR=1.99
.PARAM GLF={PWR(FLW,0.25)*NLF/1164}
.PARAM RNV={1.184*PWR(NVR,2)}
.MODEL DVN D KF={PWR(FLW,0.5)/1E11} IS=1.0E-16
* END CALC VALS
I1 0 7 10E-3
I2 0 8 10E-3
D1 7 0 DVN
D2 8 0 DVN
E1 3 6 7 8 {GLF}
R1 3 0 1E9
R2 3 0 1E9
GR3 3 6 3 6 1E-9
E2 6 4 5 0 10
R4 5 0 {RNV}
R5 5 0 {RNV}
R6 3 4 1E9
R7 4 0 1E9
E3 1 2 3 4 1
C1 1 0 1E-15
C2 2 0 1E-15
C3 1 2 1E-15
.ENDS VNSE
*$
*
.SUBCKT HPA_PD_I VCC VEE PD Vimon AGND Ninp Ninn PARAMS: Vth = 1.4 Imax = 1e-3 Imin = 3n
+ IIBP= 0.55u IIBN= 0.56u
*GBIAS VCC VEE VALUE = {IF(V(PD) >= (V(VEE)+Vth),Imax,Imin)}
GBIAS VCC VEE VALUE = {IF(V(PD) >= V(VCC),Imax,Imin)}
Ebuf VDD 0 VCC 0 1
Ginp VDD Ninp VALUE = {IF(V(PD) >= V(VCC),IIBP,0)}
Ginn VDD Ninn VALUE = {IF(V(PD) >= V(VCC),IIBN,0)}
.ENDS
*$
*
.SUBCKT HPA_PD_Sgnl CP CN DIS VP VN VCC VEE PARAMS: GAIN = 1
EVCVS VP VN VALUE = {IF(V(DIS,VEE) >= 1.4,V(CP,CN)*GAIN,0)}
.ENDS HPA_PD_Sgnl
*$
*
.SUBCKT Tran_Iout VCC VEE VIMON AGND
X_Siq1 N1 GND_FLOAT VIMON N2 Amp_Dyn_Iout_Siq1
X_Siq2 N1 GND_FLOAT VIMON N3 Amp_Dyn_Iout_Siq2
C_Ciq1 N1 GND_FLOAT 10e-12
R_Riq1 N1 VIMON 10
R_Riq2 N2 GND_FLOAT 10e3
R_Riq3 GND_FLOAT N3 10e3
G_Gsourcing VCC GND_FLOAT N3 GND_FLOAT 0.001
G_Gsinking VEE GND_FLOAT N2 GND_FLOAT 0.001
.ENDS Tran_Iout
*$
.subckt Amp_Dyn_Iout_Siq1 1 2 3 4
S_Siq1 3 4 1 2 _Siq1
RS_Siq1 1 2 1G
.MODEL _Siq1 VSWITCH Roff=1e6 Ron=1.0 Voff=0.0V Von=-0.10V
.ends Amp_Dyn_Iout_Siq1
*$
*
.subckt Amp_Dyn_Iout_Siq2 1 2 3 4
S_Siq2 3 4 1 2 _Siq2
RS_Siq2 1 2 1G
.MODEL _Siq2 VSWITCH Roff=1e6 Ron=1.0 Voff=0.0V Von=0.10V
.ends Amp_Dyn_Iout_Siq2
*$
*
.SUBCKT VCLAMP_W_SENSE_0 VCC VEE VI VO VIMON GNDF
+ PARAMS: VMAXIO = 0.1 VMINIO = 0.1 SLOPE = 0
EPCLIP VCC_CLP 0 VALUE = {V(VCC,GNDF) - SLOPE*V(VIMON,GNDF) - VMAXIO}
ENCLIP VEE_CLP 0 VALUE = {V(VEE,GNDF) - SLOPE*V(VIMON,GNDF) + VMINIO}
ECLAMP VO GNDF VALUE = {LIMIT(V(VI,GNDF), V(VCC_CLP), V(VEE_CLP))}
.ENDS
*
*$
.SUBCKT RNOISE_LESS_WILIM_0 P N PARAMS: RX = 1E-3 IMAX = 1M IMIN = -1M
GRES P N VALUE = {LIMIT(V(P,N)/RX, IMAX, IMIN)}
.ENDS
*
*$
.SUBCKT AMETER_0 VI VO VIMON GNDF
+ PARAMS: GAIN = 1
VSENSE VI VO1 DC = 0
R1 VO1 VO 1e-3
R2 VO1 VO 1e-3
R3 VO1 VO 1e-3
R4 VO1 VO 1e-3
EMETER VIMON GNDF VALUE = {I(VSENSE)*GAIN}
.ENDS
*
*$

.OPTIONS ACCT LIST OPTS ABSTOL=1uA CHGTOL=1nC DEFL=100u DEFW=100u DEFNRD=0
+ DEFNRS=0 DEFPD=0 DEFPS=0 DIGDRVF=2 DIGDRVZ=20K DIGERRDEFAULT=20 DIGERRLIMIT=0
+ DIGFREQ=10GHz DIGINITSTATE=0 DIGIOLVL=2 DIGMNTYMX=2 DIGMNTYSCALE=0.4
+ DIGOVRDRV=3 DIGTYMXSCALE=1.6 DIODE_MAX_IS=1e-6 GMIN=1n INTERPOLATION_ORDER=2
+ ITL1=200 ITL2=50 ITL4=50 PIVREL=1m PIVTOL=.1p RELTOL=10m SANDH_PRECISION=1e-4
+ SD=2.58 SEED=0 TEMP=27 TNOM=27 TRTOL=7 VNTOL=1m WIDTH=80 PRIVATEDIGITAL=0
+ PRIVATEANALOG PERFORM_M=2 RMIN=1u R_NODE_GND=1e6 PATH_TO_GROUND
+ VOLTAGE_LOOP_CHECK FLOATING_NODES_CHECK=0 NUMERIC_DERIVATIVE=0 LTHRESH=1.5
+ LONE=3.5 LZERO=.3 CSHUNT=0 RSHUNT=0 RP_FOR_ISOURCE=0 METHOD=GEAR

Спасибо: 0 
ПрофильЦитата Ответить





Сообщение: 3
Зарегистрирован: 05.06.16
Рейтинг: 0
ссылка на сообщение  Отправлено: 28.02.19 22:37. Заголовок: qaki Премного благо..


qaki

Премного благодарен!

Спасибо: 0 
ПрофильЦитата Ответить
Ответов - 27 , стр: 1 2 All [только новые]
Ответ:
1 2 3 4 5 6 7 8 9
большой шрифт малый шрифт надстрочный подстрочный заголовок большой заголовок видео с youtube.com картинка из интернета картинка с компьютера ссылка файл с компьютера русская клавиатура транслитератор  цитата  кавычки моноширинный шрифт моноширинный шрифт горизонтальная линия отступ точка LI бегущая строка оффтопик свернутый текст

показывать это сообщение только модераторам
не делать ссылки активными
Имя, пароль:      зарегистрироваться    
Тему читают:
- участник сейчас на форуме
- участник вне форума
Все даты в формате GMT  3 час. Хитов сегодня: 124
Права: смайлы да, картинки да, шрифты да, голосования нет
аватары да, автозамена ссылок вкл, премодерация откл, правка нет