On-line: гостей 0. Всего: 0 [подробнее..]
Правила: заголовок темы должен кратко и понятно отражать ее суть, нельзя писать латиницей или заглавными буквами. Сообщение, ник, аватар не должны выделяться своими размерами или стилем написания от остальных, быть читабельными, написаны литературно и достаточно грамотно.



АвторСообщение



Сообщение: 9
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 23.03.09 00:42. Заголовок: Модель IR2153 SPICE


Сделал более-менее правдоподобную модель IR2153 . Единственное , что не нашел в даташите - выходные токи драйверов LO и HO , поэтому поставил в ключах резисторы по 50 Ом.

* Model IR2153
* (C)TAU 2009
.subckt IR2153 Vcc Rt Ct COM LO VS HO VB
R5 ARB3_N1 Rt 100
Rdead ARB3_N2 ARB4_OUT 1k
Cdead ARB3_N2 COM 1.8n
RdlyH CdlyH_P ARB5_OUT 1k
CdlyH CdlyH_P COM 910p
RdlyL CdlyL_P ARB3_OUT 1k
CdlyL CdlyL_P COM 910p
BARB1 Vcc COM I=(75u+500u*(V(Vcc,COM)>8)+5m*exp(10*(V(Vcc,COM)-15.6)))*(V(Vcc,COM)>1)
*Micropower startup VCC supply current 75u ; Quiescent VCC supply current 500u; VCC zener clamp voltage 15.6V On ICC = 5mA
BARB2 ARB3_N1 COM V=V(ARB7_N1,COM)*((V(Ct,COM)<V(ARB7_N1,COM)*2/3&&V(ARB3_N1,COM)>0)||(V(Ct,COM)<V(ARB7_N1,COM)/3&&V(ARB3_N1,COM)=0))
BARB3 ARB3_OUT COM V=5*( V(ARB3_N1,COM)>8 && V(ARB3_N2,COM)>2.5 )* (V(ARB3_N3,COM)>2.5)
BARB4 ARB4_OUT COM V=5*( V(ARB3_N1,COM)>0&&V(Ct,COM)>V(ARB3_N1,COM)/3)
BARB5 ARB5_OUT COM V=5*( V(ARB3_N1,COM)<8 && V(ARB3_N2,COM)<2.5 && V(ARB7_N1,COM)>1)
BARB6 ARB7_N1 COM V=V(Vcc,COM)*((V(Vcc,COM)>8&&V(ARB7_N1,COM)>0)||(V(Vcc,COM)>9&&V(ARB7_N1,COM)=0)) ; VCC undervoltage lockout Hysteresis
BARB7 ARB3_N3 COM V=4*( V(Ct,COM)>V(ARB7_N1,COM)/6) ; * for Inhibit LO in SD mode
BARB8 Ct COM I=(V(ARB7_N1,COM)<1)*0.8m*( V(Ct,COM)>0.1) ;* ICTUV UV-mode CT pin pulldown current 0.8mA
*.IC V(Ct)=0 ;V(COM)
S1 HO VS CdlyH_P COM SVL
S2 VB HO CdlyH_P COM SVH
S3 Vcc LO CdlyL_P COM SVH
S4 LO COM CdlyL_P COM SVL
.MODEL SVH VSWITCH (RON=50 ROFF=1Meg VON=2.5 VOFF=2.45)
.MODEL SVL VSWITCH (RON=50 ROFF=1Meg VON=2.45 VOFF=2.5)
.ends IR2153

Схема для EE_SIM симулятора







Спасибо: 1 
ПрофильЦитата Ответить
Ответов - 39 , стр: 1 2 All [только новые]





Не зарегистрирован
Зарегистрирован: 01.01.70
ссылка на сообщение  Отправлено: 24.03.09 16:10. Заголовок: прописал ,пишет One ..


прописал ,пишет One or more operands are missing from an operator. For example, "sin()" would generate this message.

Спасибо: 0 
Цитата Ответить



Сообщение: 10
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 24.03.09 16:41. Заголовок: yurich, посмотрите ,..


yurich, посмотрите , может случайно произошел перенос в строке
BARB2 ARB3_N1 COM V=V(ARB7_N1,COM)*((V(Ct,COM)<V(ARB7_N1,COM)*2/3&&V(ARB3_N1,COM)>0)||(V(Ct,COM)<V(ARB7_N1,COM)/3&&V(ARB3_N1,COM)=0))

Строка должна должна быть неразрывна

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 11
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 24.03.09 18:22. Заголовок: Проверил в MICRO-CAP..


Проверил в MICRO-CAP 9
синтаксис не подходит для него
Буду искать причину

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 12
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 24.03.09 19:39. Заголовок: * Model IR2153 for M..


* Model IR2153 for Micro-Cap
* (C)TAU 2009
.subckt IR2153 Vcc Rt Ct COM LO VS HO VB
R5 ARB3_N1 Rt 100
Rdead ARB3_N2 ARB4_OUT 1k
Cdead ARB3_N2 COM 1.8n
RdlyH CdlyH_P ARB5_OUT 1k
CdlyH CdlyH_P COM 910p
RdlyL CdlyL_P ARB3_OUT 1k
CdlyL CdlyL_P COM 910p
GARB1 Vcc COM VALUE={(75u+500u*(V(Vcc,COM)>8)+5m*exp(10*(V(Vcc,COM)-15.6)))*(V(Vcc,COM)>1)}
*Micropower startup VCC supply current 75u ; Quiescent VCC supply current 500u; VCC zener clamp voltage 15.6V On ICC = 5mA
EARB2 ARB3_N1 COM VALUE=V(ARB7_N1,COM)*((V(Ct,COM)<V(ARB7_N1,COM)*2/3 AND V(ARB3_N1,COM)>0) OR (V(Ct,COM)<V(ARB7_N1,COM)/3 AND V(ARB3_N1,COM)=0))
EARB3 ARB3_OUT COM VALUE={5*( V(ARB3_N1,COM)>8 AND V(ARB3_N2,COM)>2.5 )* (V(ARB3_N3,COM)>2.5)}
EARB4 ARB4_OUT COM VALUE={5*( V(ARB3_N1,COM)>0 AND V(Ct,COM)>V(ARB3_N1,COM)/3)}
EARB5 ARB5_OUT COM VALUE={5*( V(ARB3_N1,COM)<8 AND V(ARB3_N2,COM)<2.5 AND V(ARB7_N1,COM)>1)}
EARB6 ARB7_N1 COM VALUE={V(Vcc,COM)*((V(Vcc,COM)>8 AND V(ARB7_N1,COM)>0)OR(V(Vcc,COM)>9 AND V(ARB7_N1,COM)=0))} ; VCC undervoltage lockout Hysteresis
EARB7 ARB3_N3 COM VALUE={4*( V(Ct,COM)>V(ARB7_N1,COM)/6)} ; * for Inhibit LO in SD mode
GARB8 Ct COM VALUE={(V(ARB7_N1,COM)<1)*0.8m*( V(Ct,COM)>0.1)} ;* ICTUV UV-mode CT pin pulldown current 0.8mA
S1 HO VS CdlyH_P COM SVL
S2 VB HO CdlyH_P COM SVH
S3 Vcc LO CdlyL_P COM SVH
S4 LO COM CdlyL_P COM SVL
.MODEL SVH VSWITCH (RON=50 ROFF=1Meg VON=2.5 VOFF=2.45)
.MODEL SVL VSWITCH (RON=50 ROFF=1Meg VON=2.45 VOFF=2.5)
.ends IR2153

Спасибо: 0 
ПрофильЦитата Ответить



Не зарегистрирован
Зарегистрирован: 01.01.70
ссылка на сообщение  Отправлено: 26.03.09 10:07. Заголовок: сделал стандартную с..


сделал стандартную схему включения,у пилы дребезг на вершине.при смене питания вообще генерить перестает,или работает рывками.Тау,если есть возможность ,проработайте модель пожайлуста,очень нада.Спасибо заранее

Спасибо: 0 
Цитата Ответить



Сообщение: 13
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 26.03.09 11:27. Заголовок: Дребезг на вершине м..


Дребезг на вершине может быть связан с большим шагом TMAX, уменьшите его хотя бы до четверти периода задающего генератора
При стабильном питании (хорошо отфильтрованном) размах пилы происходит строго от 1/3 до 2/3 Vcc . Так-же работает и реальная микросхема, если у Вас "шевелится" Vcc от пульсаций, размах пилы тоже будет пропорционально изменяться.
Посмотрите на вышеприведенную осциллограмму, где питание растет и размах пилы тоже пропорционально растет.
При смене питания модель отслеживает падение уровня ниже 8 вольт и перестает генерить, пока питание снова не дорастет до 9 вольт. Это нормально.

Или я неправильно понял ? , что Вы вкладываете в понятие "дребезг на вершине" - приведите осциллограмму и параметры симуляции (Tmax)
Приведите схему включения с номиналами. Провал питания может зависеть от заряда/разряда бутстрепной емкости от емкости по ножке Vcc.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 1
Зарегистрирован: 17.05.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 17.05.09 20:06. Заголовок: tay,помогите разобра..


tay,помогите разобраться неучу, желающему иметь модель IR2135. В МicroCap7 модель не работает, заявляет что"Expecting'{'. PartX. EARB2." Что делать?

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 2
Зарегистрирован: 17.05.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 17.05.09 20:08. Заголовок: Простите, описАлся. ..


Простите, описАлся. Речь идет, конечно об IR2153. Спасибо.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 3
Зарегистрирован: 17.05.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 17.05.09 20:16. Заголовок: MicroCap7 ругается..


MicroCap7 ругается на строку:
EARB2 ARB3_N1 COM VALUE=V(ARB7_N1,COM)*((V(Ct,COM)<V(ARB7_N1,COM)*2/3 AND V(ARB3_N1,COM)>0) OR (V(Ct,COM)<V(ARB7_N1,COM)/3 AND V(ARB3_N1,COM)=0))
Строку, как и весь текст модели, скопировал здесь, в этом Вашем сообщении. Записана в одну строку, без переносов. Простите за разбросанное сообщение

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 19
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 18.05.09 00:34. Заголовок: Ну так запишите как ..


Ну так запишите как оно просит , вставив фигурные скобки по краям выражения


EARB2 ARB3_N1 COM VALUE={V(ARB7_N1,COM)*((V(Ct,COM)<V(ARB7_N1,COM)*2/3 AND V(ARB3_N1,COM)>0) OR (V(Ct,COM)<V(ARB7_N1,COM)/3 AND V(ARB3_N1,COM)=0))}

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 19
Зарегистрирован: 04.03.08
Рейтинг: 0
ссылка на сообщение  Отправлено: 08.09.09 18:06. Заголовок: тау спасибо за труд..


тау
спасибо за труды . это как минимум час времени

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 7
Зарегистрирован: 31.08.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 02.11.09 18:10. Заголовок: microcap 7 матюкаетс..


microcap 7 матюкается вот так



Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 23
Зарегистрирован: 04.03.08
Рейтинг: 0
ссылка на сообщение  Отправлено: 11.11.09 19:56. Заголовок: тау вот и понадобил..


тау
вот и понадобилась
а как вставлять модель в схему ?

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 58
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 12.11.09 11:44. Заголовок: 12val12, посмотрите ..


12val12, посмотрите тут http://www.microcap.jino-net.ru/ - там описана процедура.

lintech , я не могу ничего подсказать по 7-му , к сожалению.



Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 25
Зарегистрирован: 04.03.08
Рейтинг: 0
ссылка на сообщение  Отправлено: 12.11.09 18:52. Заголовок: тау Спасибо вчера с..


тау
Спасибо вчера сам подключил ..но модель не работает так как нужно
(microcap9)

http://slil.ru/28196129

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 26
Зарегистрирован: 04.03.08
Рейтинг: 0
ссылка на сообщение  Отправлено: 12.11.09 19:18. Заголовок: тау изменение шага ..


тау изменение шага (100 - 10 - 1 нсек ) влияет на сигналы но самым непредсказуемым образом
глобальные параметры не влияют принципиально (STandart def -- power def)

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 61
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 13.11.09 00:27. Заголовок: вероятно вы не так п..


вероятно вы не так подцепили ножки символа к цепям модели. почему-то ножек 9 а цепей в subckt всего 8 .
Проверьте , если не получится - вложите проект тут , я посмотрю.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 27
Зарегистрирован: 04.03.08
Рейтинг: 0
ссылка на сообщение  Отправлено: 13.11.09 16:40. Заголовок: тау перецепил к друг..


тау перецепил к другому @shape@ 4х выводному и модель прямо в файле схемы
итог такой же
http://slil.ru/28200061
не могли бы вы сделать структуру макросом- было бы проще нагляднее и легче корректировать

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 63
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 14.11.09 04:07. Заголовок: нашел ошибку, проявл..


нашел ошибку, проявляющуюся только в Micro-Cap !!! Оказывается , сравнение с нулем - страшное зло в микрокапе, хотя остальные симуляторы , с которыми приходилось работать , к операции" =0 " относятся нормально

ВОт исправленный текст модели
.subckt IR2153 Vcc Rt Ct COM LO VS HO VB
R5 ARB3_N1 Rt 100
Rdead ARB3_N2 ARB4_OUT 1k
Cdead ARB3_N2 COM 1.8n
RdlyH CdlyH_P ARB5_OUT 1k
CdlyH CdlyH_P COM 910p
RdlyL CdlyL_P ARB3_OUT 1k
CdlyL CdlyL_P COM 910p
GARB1 Vcc COM VALUE={(75u+500u*(V(Vcc,COM)>8)+5m*exp(10*(V(Vcc,COM)-15.6)))*(V(Vcc,COM)>1)}
*Micropower startup VCC supply current 75u ; Quiescent VCC supply current 500u; VCC zener clamp voltage 15.6V On ICC = 5mA
EARB2 ARB3_N1 COM VALUE={V(ARB7_N1,COM)*((V(Ct,COM)<V(ARB7_N1,COM)*2/3 AND V(ARB3_N1,COM)>4) OR (V(Ct,COM)<V(ARB7_N1,COM)/3 AND V(ARB3_N1,COM)<3))}
EARB3 ARB3_OUT COM VALUE={5*( V(ARB3_N1,COM)>8 AND V(ARB3_N2,COM)>2.5 )* (V(ARB3_N3,COM)>2.5)}
EARB4 ARB4_OUT COM VALUE={5*( V(ARB3_N1,COM)>0.1 AND V(Ct,COM)>V(ARB3_N1,COM)/3)}
EARB5 ARB5_OUT COM VALUE={5*( V(ARB3_N1,COM)<8 AND V(ARB3_N2,COM)<2.5 AND V(ARB7_N1,COM)>1)}
EARB6 ARB7_N1 COM VALUE={V(Vcc,COM)*((V(Vcc,COM)>8 AND V(ARB7_N1,COM)>0.2)OR(V(Vcc,COM)>9 AND V(ARB7_N1,COM)<0.1))} ;* VCC undervoltage lockout Hysteresis
EARB7 ARB3_N3 COM VALUE={4*( V(Ct,COM)>V(ARB7_N1,COM)/6)} ; * for Inhibit LO in SD mode
GARB8 Ct COM VALUE={(V(ARB7_N1,COM)<1)*0.8m*( V(Ct,COM)>0.1)} ;* ICTUV UV-mode CT pin pulldown current 0.8mA
S1 HO VS CdlyH_P COM SVL
S2 VB HO CdlyH_P COM SVH
S3 Vcc LO CdlyL_P COM SVH
S4 LO COM CdlyL_P COM SVL
.MODEL SVH VSWITCH (RON=50 ROFF=1Meg VON=2.5 VOFF=2.45)
.MODEL SVL VSWITCH (RON=50 ROFF=1Meg VON=2.45 VOFF=2.5)
.ends IR2153



файл с поправленным пректом .cir
http://slil.ru/28202226

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 18
Зарегистрирован: 31.08.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 14.11.09 07:27. Заголовок: Всё ровно в Dynamic ..


Всё ровно в Dynamic DC матюкается ! :(
Сообщение такое же как я показывал несколькими постами выше.

Спасибо: 0 
ПрофильЦитата Ответить
Ответов - 39 , стр: 1 2 All [только новые]
Ответ:
1 2 3 4 5 6 7 8 9
большой шрифт малый шрифт надстрочный подстрочный заголовок большой заголовок видео с youtube.com картинка из интернета картинка с компьютера ссылка файл с компьютера русская клавиатура транслитератор  цитата  кавычки моноширинный шрифт моноширинный шрифт горизонтальная линия отступ точка LI бегущая строка оффтопик свернутый текст

показывать это сообщение только модераторам
не делать ссылки активными
Имя, пароль:      зарегистрироваться    
Тему читают:
- участник сейчас на форуме
- участник вне форума
Все даты в формате GMT  3 час. Хитов сегодня: 120
Права: смайлы да, картинки да, шрифты да, голосования нет
аватары да, автозамена ссылок вкл, премодерация откл, правка нет