On-line: гостей 1. Всего: 1 [подробнее..]
Правила: заголовок темы должен кратко и понятно отражать ее суть, нельзя писать латиницей или заглавными буквами. Сообщение, ник, аватар не должны выделяться своими размерами или стилем написания от остальных, быть читабельными, написаны литературно и достаточно грамотно.



АвторСообщение



Сообщение: 9
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 23.03.09 00:42. Заголовок: Модель IR2153 SPICE


Сделал более-менее правдоподобную модель IR2153 . Единственное , что не нашел в даташите - выходные токи драйверов LO и HO , поэтому поставил в ключах резисторы по 50 Ом.

* Model IR2153
* (C)TAU 2009
.subckt IR2153 Vcc Rt Ct COM LO VS HO VB
R5 ARB3_N1 Rt 100
Rdead ARB3_N2 ARB4_OUT 1k
Cdead ARB3_N2 COM 1.8n
RdlyH CdlyH_P ARB5_OUT 1k
CdlyH CdlyH_P COM 910p
RdlyL CdlyL_P ARB3_OUT 1k
CdlyL CdlyL_P COM 910p
BARB1 Vcc COM I=(75u+500u*(V(Vcc,COM)>8)+5m*exp(10*(V(Vcc,COM)-15.6)))*(V(Vcc,COM)>1)
*Micropower startup VCC supply current 75u ; Quiescent VCC supply current 500u; VCC zener clamp voltage 15.6V On ICC = 5mA
BARB2 ARB3_N1 COM V=V(ARB7_N1,COM)*((V(Ct,COM)<V(ARB7_N1,COM)*2/3&&V(ARB3_N1,COM)>0)||(V(Ct,COM)<V(ARB7_N1,COM)/3&&V(ARB3_N1,COM)=0))
BARB3 ARB3_OUT COM V=5*( V(ARB3_N1,COM)>8 && V(ARB3_N2,COM)>2.5 )* (V(ARB3_N3,COM)>2.5)
BARB4 ARB4_OUT COM V=5*( V(ARB3_N1,COM)>0&&V(Ct,COM)>V(ARB3_N1,COM)/3)
BARB5 ARB5_OUT COM V=5*( V(ARB3_N1,COM)<8 && V(ARB3_N2,COM)<2.5 && V(ARB7_N1,COM)>1)
BARB6 ARB7_N1 COM V=V(Vcc,COM)*((V(Vcc,COM)>8&&V(ARB7_N1,COM)>0)||(V(Vcc,COM)>9&&V(ARB7_N1,COM)=0)) ; VCC undervoltage lockout Hysteresis
BARB7 ARB3_N3 COM V=4*( V(Ct,COM)>V(ARB7_N1,COM)/6) ; * for Inhibit LO in SD mode
BARB8 Ct COM I=(V(ARB7_N1,COM)<1)*0.8m*( V(Ct,COM)>0.1) ;* ICTUV UV-mode CT pin pulldown current 0.8mA
*.IC V(Ct)=0 ;V(COM)
S1 HO VS CdlyH_P COM SVL
S2 VB HO CdlyH_P COM SVH
S3 Vcc LO CdlyL_P COM SVH
S4 LO COM CdlyL_P COM SVL
.MODEL SVH VSWITCH (RON=50 ROFF=1Meg VON=2.5 VOFF=2.45)
.MODEL SVL VSWITCH (RON=50 ROFF=1Meg VON=2.45 VOFF=2.5)
.ends IR2153

Схема для EE_SIM симулятора







Спасибо: 1 
ПрофильЦитата Ответить
Ответов - 39 , стр: 1 2 All [только новые]





Сообщение: 64
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 14.11.09 16:19. Заголовок: Dynamic DC так же к..


Dynamic DC так же как и AC анализ для некоторых схем принципиально невозможен. Причина в том, что схема сама по себе что-то генерирует (используются внутренние генераторы в схеме, которые микрокап не может остановить) Поэтому микрокап ждет-ждет, когда же установятся и стабилизируются режимы по постоянному току , а они никак не останавливаются
Поэтому и нет сходимости в понятиях DC . Но Вы можете остановить генерёж по ножке Ct в данной схеме, например замкнув на землю . Dynamic DC тогда станет возможен.

Спасибо: 1 
ПрофильЦитата Ответить



Сообщение: 67
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 0
ссылка на сообщение  Отправлено: 14.11.09 17:15. Заголовок: 12val12 пишет: не м..


12val12 пишет:

 цитата:
не могли бы вы сделать структуру макросом- было бы проще нагляднее и легче корректировать


Неа, не умею , чесслово. я микрокапом очень редко пользуюсь.

Спасибо: 1 
ПрофильЦитата Ответить



Сообщение: 28
Зарегистрирован: 04.03.08
Рейтинг: 0
ссылка на сообщение  Отправлено: 14.11.09 18:04. Заголовок: тау спасибо спасиб..


тау
спасибо
спасибо
спасибо



Спасибо: 0 
ПрофильЦитата Ответить
администратор




Сообщение: 850
Зарегистрирован: 02.05.07
Откуда: Россия, Смоленск
Рейтинг: 2
ссылка на сообщение  Отправлено: 15.11.09 15:08. Заголовок: Всё ровно в Dynamic ..



 цитата:
Всё ровно в Dynamic DC матюкается


А чего ему не матюкаться? Ведь это разновидность расчета по постоянному току. Какой режим по постоянному току может быть в схеме с периодической коммутацией ключа? Там, как минимум, два установившихся режима - когда ключ замкнут и когда ключ разомкнут. А выходное напряжение - результат временнОго усреднения этих двух режимов.
Поэтому попытка исследования схемы с периодической коммутацией в режиме по постоянному току абсурдна по сути.
Хочу обратить внимание, в этом режиме нельзя исследовать и схемы с элементами памяти (частным случаем которых является триггер), поскольку состояние такой схемы зависит не только от токов и напряжений в текущий момент времени, но и от предварительного состояния элементов памяти. И эти состояния расчет по постоянному току принципиально учесть не может.
Вообще, вот как осуществляется Dynamic DC:

 цитата:
Dynamic DC Analysis — динамический анализ эквивалентной схемы замещения для постоянных составляющих токов и напряжений. При выполнении этого вида анализа напряжения в узлах схемы, токи компонентов и со-стояния полупроводниковых приборов (ON, OFF, SAT, LIN, и т.д.) выводятся непосредственно на схему устройства. Никаких графиков для этого режима не строится, поскольку не производится расчета каких-либо зависимостей. При модификации схемы программа сразу же рассчитывает результат изменений. Используется для расчета рабочей точки усилителей, анализа режима работы стабилизаторов напряжения или тока и т.п.
В этом режиме производится расчет установившегося режима работы схемы. Программа вычисляет, какие величины токов и напряжений установятся в схеме, когда все переходные процессы закончатся (т.е. в момент времени, стремящейся к бесконечности). При этом принципиальная схема устройства условно подвергается определенной модификации: удаляются все реактивные компоненты. Конденсаторы заменяются разрывом (резисторами с бесконечным сопротивлением), индуктивности закорачиваются (заменяются резисторами с нулевым сопротивлением), а источники переменных сигналов заменяются постоянными величинами (постоянными составляющими этих сигналов, либо иными величинами, заданными непосредственно в модели источника сигнала).



Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 20
Зарегистрирован: 31.08.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 16.11.09 13:38. Заголовок: Спасибо за разъяснен..


Спасибо за разъяснения, теперь понятно почему он матюкался.

Спасибо: 0 
ПрофильЦитата Ответить



Не зарегистрирован
Зарегистрирован: 01.01.70
ссылка на сообщение  Отправлено: 04.04.13 01:13. Заголовок: тау Здравствуйте, ск..


тау Здравствуйте, скиньте, пожалуйста, заново модель IR2153, если не сложно, а то та ссылка, которую вы давали, уже устарела

Спасибо: 0 
Цитата Ответить



Сообщение: 104
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 07.04.13 09:03. Заголовок: Как-то скачал еще од..


Как-то скачал еще одну версию модели IR2153 производства TAU. Но что-то глючит.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 25
Зарегистрирован: 21.08.07
Рейтинг: 0
ссылка на сообщение  Отправлено: 07.04.13 15:04. Заголовок: Модель IR2153 SPICE


.subckt IR2153 Vcc Rt Ct COM LO VS HO VB
R5 ARB3_N1 Rt 100
Rdead ARB3_N2 ARB4_OUT 1k
Cdead ARB3_N2 COM 1.8n
RdlyH CdlyH_P ARB5_OUT 1k
CdlyH CdlyH_P COM 910p
RdlyL CdlyL_P ARB3_OUT 1k
CdlyL CdlyL_P COM 910p
GARB1 Vcc COM VALUE={(75u+500u*(V(Vcc,COM)>8)+5m*exp(10*(V(Vcc,COM)-15.6)))*(V(Vcc,COM)>1)}
*Micropower startup VCC supply current 75u ; Quiescent VCC supply current 500u; VCC zener clamp voltage 15.6V On ICC = 5mA
EARB2 ARB3_N1 COM VALUE={V(ARB7_N1,COM)*((V(Ct,COM)<V(ARB7_N1,COM)*2/3 AND V(ARB3_N1,COM)>4) OR (V(Ct,COM)<V(ARB7_N1,COM)/3 AND V(ARB3_N1,COM)<3))}
EARB3 ARB3_OUT COM VALUE={5*( V(ARB3_N1,COM)>8 AND V(ARB3_N2,COM)>2.5 )* (V(ARB3_N3,COM)>2.5)}
EARB4 ARB4_OUT COM VALUE={5*( V(ARB3_N1,COM)>0.1 AND V(Ct,COM)>V(ARB3_N1,COM)/3)}
EARB5 ARB5_OUT COM VALUE={5*( V(ARB3_N1,COM)<8 AND V(ARB3_N2,COM)<2.5 AND V(ARB7_N1,COM)>1)}
EARB6 ARB7_N1 COM VALUE={V(Vcc,COM)*((V(Vcc,COM)>8 AND V(ARB7_N1,COM)>0.2)OR(V(Vcc,COM)>9 AND V(ARB7_N1,COM)<0.1))} ;* VCC undervoltage lockout Hysteresis
EARB7 ARB3_N3 COM VALUE={4*( V(Ct,COM)>V(ARB7_N1,COM)/6)} ; * for Inhibit LO in SD mode
GARB8 Ct COM VALUE={(V(ARB7_N1,COM)<1)*0.8m*( V(Ct,COM)>0.1)} ;* ICTUV UV-mode CT pin pulldown current 0.8mA
S1 HO VS CdlyH_P COM SVL
S2 VB HO CdlyH_P COM SVH
S3 Vcc LO CdlyL_P COM SVH
S4 LO COM CdlyL_P COM SVL
.MODEL SVH VSWITCH (RON=50 ROFF=1Meg VON=2.5 VOFF=2.45)
.MODEL SVL VSWITCH (RON=50 ROFF=1Meg VON=2.45 VOFF=2.5)
.ends IR2153

Спасибо: 1 
ПрофильЦитата Ответить



Сообщение: 111
Зарегистрирован: 04.02.09
Откуда: Москва
Рейтинг: 1
ссылка на сообщение  Отправлено: 22.04.13 00:18. Заголовок: Noboru пишет: тау ..


Noboru пишет:

 цитата:
тау Здравствуйте, скиньте, пожалуйста, заново модель IR2153, если не сложно, а то та ссылка, которую вы давали, уже устарела


модель доработанная для 9-й версии М-CAp находится в этой теме на первой странице в соообщении от 14.11.09
в прямом тексте . Схемный же файл с данной моделью за давностью времен утерян .

Спасибо kreking-у за верную подсказку.


qaki пишет:

 цитата:

Как-то скачал еще одну версию модели IR2153 производства TAU. Но что-то глючит

А эта моделька тоже из этой темы , но более ранняя, еще до того как были замечены её недостатки 14.11.2009 .

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 123
Зарегистрирован: 24.03.12
Рейтинг: 1
ссылка на сообщение  Отправлено: 26.06.13 15:21. Заголовок: модель не работает. ..


модель не работает.
схема http://zalil.ru/34606701

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 124
Зарегистрирован: 24.03.12
Рейтинг: 1
ссылка на сообщение  Отправлено: 26.06.13 20:02. Заголовок: не заметил ошибку в ..


не заметил ошибку в схеме.работает.но что то переключение пологое.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 24
Зарегистрирован: 06.09.12
Рейтинг: 0
ссылка на сообщение  Отправлено: 26.07.13 01:15. Заголовок: тау пишет: Единстве..


тау пишет:

 цитата:
Единственное , что не нашел в даташите - выходные токи драйверов LO и HO , поэтому поставил в ключах резисторы по 50 Ом.


IO+ Output source current - 180 mA
IO- Output sink current - 260 mA

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 191
Зарегистрирован: 24.03.12
Откуда: Россия, Саратов
Рейтинг: 1
ссылка на сообщение  Отправлено: 24.02.14 23:38. Заголовок: тау,не могли бы вы п..


тау,не могли бы вы подправить модель ir2153.из-за пологого переключения
получаются большие сквозные токи через силовые транзисторы.заметил только
сейчас.токи порядка 17А.удалось ограничить дросселем по питанию.
но как то все равно кривовато.то есть пауза как по даташиту отсутствует.
или я что то напутал?

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 150
Зарегистрирован: 22.04.09
Рейтинг: 0
ссылка на сообщение  Отправлено: 25.02.14 19:38. Заголовок: losik Качайте отсюд..


losik
Качайте отсюда
http://yadi.sk/d/tHE8OEmVJXvUP
Это очень похоже на модель Тау, но в ней кто-то слегка покопался, после чего она стала нормально работать. По величине токов питания не смотрел, но выходные импульсы в порядке. Живые микрухи без подключения к затворам стойки полумоста вылетают сразу. Может быть и Вы моделировали такой режим? И еще. Эта микруха не любит IRF740 видимо из-за большой входной емкости.

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 76
Зарегистрирован: 04.03.13
Рейтинг: 0
ссылка на сообщение  Отправлено: 31.07.17 05:08. Заголовок: qaki пишет: Качайте..


qaki пишет:

 цитата:
Качайте отсюда



Могли бы вы повторить ссылку?

Импортирую модель от топик-стартёра, какой корпус ставить? Ставлю PWM, получается вот это:



Что с этим делать?

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 227
Зарегистрирован: 22.04.09
Рейтинг: 1
ссылка на сообщение  Отправлено: 31.07.17 23:32. Заголовок: Cahes пишет: Что с ..


Cahes пишет:

 цитата:
Что с этим делать?



Spice-листинг работающей модели
.subckt IR2153 Vcc Rt Ct COM LO VS HO VB
R5 ARB3_N1 Rt 100
Rdead ARB3_N2 ARB4_OUT 1k
Cdead ARB3_N2 COM 1.8n
RdlyH CdlyH_P ARB5_OUT 1k
CdlyH CdlyH_P COM 910p
RdlyL CdlyL_P ARB3_OUT 1k
CdlyL CdlyL_P COM 910p
GARB1 Vcc COM VALUE={(75u+500u*(V(Vcc,COM)>8)+5m*exp(10*(V(Vcc,COM)-15.6)))*(V(Vcc,COM)>1)}

* Micropower startup VCC supply current 75u
* Quiescent VCC supply current 500u;
* VCC zener clamp voltage 15.6V On ICC = 5mA

EARB2 ARB3_N1 COM VALUE={V(ARB7_N1,COM)*(((V(Ct,COM)<(V(ARB7_N1,COM)*2/3)) & (V(ARB3_N1,COM)>4)) | ((V(Ct,COM)<(V(ARB7_N1,COM)/3)) & (V(ARB3_N1,COM)<3)))}

EARB3 ARB3_OUT COM VALUE={5*( V(ARB3_N1,COM)>8 & V(ARB3_N2,COM)>2.5 )* (V(ARB3_N3,COM)>2.5)}
EARB4 ARB4_OUT COM VALUE={5*( V(ARB3_N1,COM)>0.1 & V(Ct,COM)>V(ARB3_N1,COM)/3)}
EARB5 ARB5_OUT COM VALUE={5*( V(ARB3_N1,COM)<8 & V(ARB3_N2,COM)<2.5 & V(ARB7_N1,COM)>1)}
EARB6 ARB7_N1 COM VALUE={V(Vcc,COM)*((V(Vcc,COM)>8 & V(ARB7_N1,COM)>0.2)|(V(Vcc,COM)>9 & V(ARB7_N1,COM)<0.1))}
* VCC undervoltage lockout Hysteresis

EARB7 ARB3_N3 COM VALUE={4*( V(Ct,COM)>V(ARB7_N1,COM)/6)} ; * for Inhibit LO in SD mode
GARB8 Ct COM VALUE={(V(ARB7_N1,COM)<1)*0.8m*( V(Ct,COM)>0.1)}; * ICTUV UV-mode CT pin pulldown current 0.8mA

.IC V(Ct)=0 V(LO)=0; * V(Vs)=0; * V(COM)
S1 HO VS CdlyH_P COM SVL
S2 VB HO CdlyH_P COM SVH
S3 Vcc LO CdlyL_P COM SVH
S4 LO COM CdlyL_P COM SVL


.MODEL SVH VSWITCH (RON=35 ROFF=1Meg VON=2.5 VOFF=2.45)
.MODEL SVL VSWITCH (RON=18 ROFF=.1meg VON=2.45 VOFF=2.5)

.ends IR2153

Залейте эту галимотню в библиотечный файл .LIB
Корпус, то бишь Shape, берите a_dip8. Распиновка по Datasheet
Моделируйте на здоровье.



Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 84
Зарегистрирован: 04.03.13
Рейтинг: 0
ссылка на сообщение  Отправлено: 30.12.17 14:22. Заголовок: locik пишет: из-за ..


locik пишет:

 цитата:
из-за пологого переключения...или я что то напутал?


У неё слабые выходы: максимальный ток не указан открытие/закрытие - 250/400ма, она не может сама раскачать затворы больше нанофарада, потому и фронты не вертикальные, пологие - как у вас. Резисторы в затворах надо по 60Ом, и обратные диоды параллельно им желательно. Правда - всё это мелочи для такой мелочёвой микросхемы.

qaki пишет:

 цитата:
...подключения к затворам стойки полумоста...


Что такое - "стойка полумоста"?

qaki пишет:

 цитата:
Корпус, то бишь Shape, берите a_dip8


Странно: я использовал раньше этот корпус но брехало, с вашей моделью получилось с первого раза, "гора с плеч"... Спасибо.



Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 85
Зарегистрирован: 04.03.13
Рейтинг: 0
ссылка на сообщение  Отправлено: 30.12.17 15:24. Заголовок: Моделирую IR2153: мо..


......................

Спасибо: 0 
ПрофильЦитата Ответить



Сообщение: 3
Зарегистрирован: 02.12.17
Рейтинг: 0
ссылка на сообщение  Отправлено: 26.03.18 00:04. Заголовок: пытаюсь моделировать схему с IR2153


При попытке моделировать в MicroCap9 transient analiz схемы с последним вариантом модели получаю ответ
"hidden mode 8 is missing". Переводчик помощи переводит, что это бывает, когда не совпадает количество ног в схеме и в модели. Какую то из ног не надо подключать?

Спасибо: 0 
ПрофильЦитата Ответить
Ответов - 39 , стр: 1 2 All [только новые]
Ответ:
1 2 3 4 5 6 7 8 9
большой шрифт малый шрифт надстрочный подстрочный заголовок большой заголовок видео с youtube.com картинка из интернета картинка с компьютера ссылка файл с компьютера русская клавиатура транслитератор  цитата  кавычки моноширинный шрифт моноширинный шрифт горизонтальная линия отступ точка LI бегущая строка оффтопик свернутый текст

показывать это сообщение только модераторам
не делать ссылки активными
Имя, пароль:      зарегистрироваться    
Тему читают:
- участник сейчас на форуме
- участник вне форума
Все даты в формате GMT  3 час. Хитов сегодня: 54
Права: смайлы да, картинки да, шрифты да, голосования нет
аватары да, автозамена ссылок вкл, премодерация откл, правка нет